home *** CD-ROM | disk | FTP | other *** search
/ Alles Voor Internet / Tout Pour Internet / alles voor internet.iso / MacInternet™ / Telnet / Comet.3.0.7 Folder / ibm-host-software / FTERR.ASSEMBLE < prev    next >
Text File  |  1992-09-09  |  17KB  |  207 lines
  1. FTERR    TITLE 'ERROR MESSAGES FOR FT3270'                              00010000
  2. *********************************************************************   00020000
  3. *   THIS MODULE PROCESSES ERRORS THAT OCCUR IN FT3270 AND FTCMS.    *   00030000
  4. *   THE ERROR CODE FROM THE CALLING PROGRAM IS PASSED IN R3.        *   00040000
  5. *   IF THERE IS AN RC FROM A CMS MACRO, IT IS PASSED IN R2.         *   00050000
  6. *                                                                   *   00060000
  7. *            PETER HOYT          CORNELL COMPUTER SERVICES          *   00070000
  8. *            VERSION 2.0         AUGUST 30, 1987                    *   00080000
  9. *                                                                   *   00090000
  10. *   SOURCE FILE SEQUENCED FOR FUTURE MAINTANENCE.  LARRY CHACE      *   00100000
  11. *                                                                   *   00110000
  12. *********************************************************************   00120000
  13. FTERR    CSECT                                                          00130000
  14.          USING FTERR,R12                                                00140000
  15.          STM   R14,R12,12(R13)     SAVE THE CALLER'S THINGS.            00150000
  16.          LR    R12,R15             GET OUR BASE ADDRESS.                00160000
  17.          ST    R13,SAVEAREA+4      SAVE HIS SAVE AREA AND               00170000
  18.          LA    R13,SAVEAREA          GET OURS.                          00180000
  19. *                                                                       00190000
  20.          ST    R3,RETCODE          DECIDE WHICH CATEGORY OF ERROR       00200000
  21.          C     R3,=F'40'              PARAMETER ERRORS                  00210000
  22.          BC    4,FTERR9               LESS IS ERROR ERROR               00220000
  23.          C     R3,=F'50'              CMS ERRORS                        00230000
  24.          BC    4,FTERR1               LESS IS PARM  ERROR               00240000
  25.          C     R3,=F'60'              NEGOT & MISC ERRORS               00250000
  26.          BC    4,FTERR2               LESS IS CMS   ERROR               00260000
  27.          C     R3,=F'81'              NEGOT & PC   ERRORS               00270000
  28.          BC    4,FTERR3               LESS IS NEGOT ERROR               00280000
  29.          B     FTERR4              ALL ELSE GOES TO PC ERRORS           00290000
  30. *                                                                       00300000
  31. FTERR9   LA    R9,PCERR88                                               00310000
  32.          LA    R8,PCERR89                                               00320000
  33. *                                                                       00330000
  34. ****  PUT OUT ERROR MESSAGE & RETURN WITH A NON-ZERO RETURN CODE        00340000
  35. *                                                                       00350000
  36. ADONE    SR    R8,R9               TO GET LENGTH OF STRING              00360000
  37.          WRTERM (R9),(R8)                                               00370000
  38.          L     R15,RETCODE         GET EVIL RETURN CODE.                00380000
  39.          L     R13,4(,R13)         RESTORE EVERYTHING                   00390000
  40.          L     R14,12(R13)           FROM THE CALLER                    00400000
  41.          LM    R0,R12,20(R13)        EXCEPT R15!                        00410000
  42.          BR    R14                                                      00420000
  43. PCERR88  DC    C'Unable to interpret PC error.'                         00430000
  44. PCERR89  DS    0C                                                       00440000
  45.          EJECT                                                          00450000
  46. *---------------------------------------------------------------------* 00460000
  47. *        PARAMETER ERRORS:    RC = 40 THRU 49                         * 00470000
  48. *---------------------------------------------------------------------* 00480000
  49. FTERR1   DS    0H                                                       00490000
  50.          S     R3,=F'40'           USE R3 AS INDEX INTO TABLE           00500000
  51.          C     R3,=F'8'            MAKE SURE IN RANGE                   00510000
  52.          BC    2,FTERR9                                                 00520000
  53.          SLL   R3,2                EACH ENTRY 4 BYTES                   00530000
  54.          L     R9,PERRLST(R3)                                           00540000
  55.          A     R3,=F'4'            TO DETERMINE LENGTH                  00550000
  56.          L     R8,PERRLST(R3)                                           00560000
  57.          B     ADONE                                                    00570000
  58. *                                                                       00580000
  59. PERR0M   DC    C'Args: DOS filespec, control, CMS fn, ft, fm'           00590000
  60. PERR1M   DC    C'First byte of 2nd arg must be "D" or "U".'             00600000
  61. PERR2M   DC    C'Second byte of 2nd arg must be "B", "T", or "D".'      00610000
  62. PERR3M   DC    C'Third byte of 2nd arg must be "R" or "N".'             00620000
  63. PERR4M   DC    C'Lrecl must be numeric.'                                00630000
  64. PERR5M   DC    C'Disk not accessed.'                                    00640000
  65. PERR6M   DC    C'CMS file already exists.'                              00650000
  66. PERR7M   DC    C'Lrecl must not exceed 65535!'                          00660000
  67. PERR8M   DC    C'Local filespec must contain 1 - 80 characters!'        00670000
  68. PERR99   DS    0C                                                       00680000
  69. PERRLST  DC    A(PERR0M)                                                00690000
  70.          DC    A(PERR1M)                                                00700000
  71.          DC    A(PERR2M)                                                00710000
  72.          DC    A(PERR3M)                                                00720000
  73.          DC    A(PERR4M)                                                00730000
  74.          DC    A(PERR5M)                                                00740000
  75.          DC    A(PERR6M)                                                00750000
  76.          DC    A(PERR7M)                                                00760000
  77.          DC    A(PERR8M)                                                00770000
  78.          DC    A(PERR99)                                                00780000
  79.          EJECT                                                          00790000
  80. *---------------------------------------------------------------------* 00800000
  81. *        CMS ERRORS       RC: 50 THRU 59                              * 00810000
  82. *---------------------------------------------------------------------* 00820000
  83. FTERR2   DS    0H                                                       00830000
  84.          S     R3,=F'50'                                                00840000
  85.          BZ    NOMEM                                                    00850000
  86.          S     R3,=F'1'                                                 00860000
  87.          BZ    TOOBIG                                                   00870000
  88.          S     R3,=F'1'                                                 00880000
  89.          BZ    FSSERR                                                   00890000
  90.          S     R3,=F'1'                                                 00900000
  91.          BZ    FSRERR                                                   00910000
  92.          S     R3,=F'1'                                                 00920000
  93.          BNZ   FTERR9               ERROR OUT OF RANGE                  00930000
  94. *                                                                       00940000
  95. FSWERR   ST    R2,RETCODE           FSWRITE FAILURE                     00950000
  96.          LA    R9,CMSERR5           RC = 54                             00960000
  97.          LA    R8,CMSERR99                                              00970000
  98.          B     ADONE                                                    00980000
  99. NOMEM    LA    R9,CMSERR0           RC = 50                             00990000
  100.          LA    R8,CMSERR1                                               01000000
  101.          B     ADONE                                                    01010000
  102. TOOBIG   LA    R9,CMSERR1           RC = 51                             01020000
  103.          LA    R8,CMSERR2                                               01030000
  104.          B     ADONE                                                    01040000
  105. FSSERR   ST    R2,RETCODE           FSSTATE FAILURE                     01050000
  106.          C     R2,=F'28'            RC = 52                             01060000
  107.          BZ    FSSERR1                                                  01070000
  108.          LA    R9,CMSERR2                                               01080000
  109.          LA    R8,CMSERR3                                               01090000
  110.          B     ADONE                                                    01100000
  111. FSSERR1  LA    R9,CMSERR3                                               01110000
  112.          LA    R8,CMSERR4                                               01120000
  113.          B     ADONE                                                    01130000
  114. FSRERR   ST    R2,RETCODE           FSREAD FAILURE                      01140000
  115.          LA    R9,CMSERR4           RC = 53                             01150000
  116.          LA    R8,CMSERR5                                               01160000
  117.          B     ADONE                                                    01170000
  118. CMSERR0  DC    C'Failure to allocate CMS record buffer via DMSFREE.'    01180000
  119. CMSERR1  DC    C'Insufficient space on CMS minidisk.'                   01190000
  120. CMSERR2  DC    C'Improper file specification.'                          01200000
  121. CMSERR3  DC    C'CMS file not found!'                                   01210000
  122. CMSERR4  DC    C'Error doing FSREAD'                                    01220000
  123. CMSERR5  DC    C'Error doing FSWRITE'                                   01230000
  124. CMSERR99 DS    0C                                                       01240000
  125.          EJECT                                                          01250000
  126. *---------------------------------------------------------------------* 01260000
  127. *  NEGOTIATION AND MISCELLANEOUS ERRORS         RC: 60 THRU 75        * 01270000
  128. *---------------------------------------------------------------------* 01280000
  129. FTERR3   DS    0H                                                       01290000
  130.          S     R3,=F'60'           USE R3 AS INDEX INTO TABLE           01300000
  131.          C     R3,=F'7'            MAKE SURE IN RANGE                   01310000
  132.          BC    2,FTERR9                                                 01320000
  133.          SLL   R3,2                EACH ENTRY 4 BYTES                   01330000
  134.          L     R9,NEGOLST(R3)                                           01340000
  135.          A     R3,=F'4'            TO DETERMINE LENGTH                  01350000
  136.          L     R8,NEGOLST(R3)                                           01360000
  137.          B     ADONE                                                    01370000
  138. *                                                                       01380000
  139. NEGERR0M DC    C'You must be running TN3270 or C19 on your PC or Mac.'  01390000
  140. NEGERR1M DC    C'Improper data format from PC.'                         01400000
  141. NEGERR2M DC    C'Device I/O error'                                      01410000
  142. NEGERR3M DC    C'User requested break via PA1.'                         01420000
  143. NEGERR4M DC    C'PC rejects this version of FT3270.'                    01430000
  144. NEGERR5M DC    C'Ft3270 rejects this version of PC program.'            01440000
  145. NEGERR6M DC    C'Invalid checksum in initial packet.'                   01450000
  146. NEGERR7M DC    C'Internal data error.'                                  01460000
  147. NEGERR99 DS    0C                                                       01470000
  148. NEGOLST  DC    A(NEGERR0M)                                              01480000
  149.          DC    A(NEGERR1M)                                              01490000
  150.          DC    A(NEGERR2M)                                              01500000
  151.          DC    A(NEGERR3M)                                              01510000
  152.          DC    A(NEGERR4M)                                              01520000
  153.          DC    A(NEGERR5M)                                              01530000
  154.          DC    A(NEGERR6M)                                              01540000
  155.          DC    A(NEGERR7M)                                              01550000
  156.          DC    A(NEGERR99)                                              01560000
  157.          EJECT                                                          01570000
  158. *---------------------------------------------------------------------* 01580000
  159. *   ERRORS BASED ON RETURN CODE FROM PC   RC: 81 THRU 95              * 01590000
  160. *---------------------------------------------------------------------* 01600000
  161. FTERR4   DS    0H                                                       01610000
  162.          N     R3,=F'95'             GET THE ERROR CODE IN RANGE        01620000
  163.          C     R3,=F'90'                                                01630000
  164.          BC    2,FTERR9                                                 01640000
  165.          ST    R3,RETCODE            GET THE ERROR FROM THE TABLE       01650000
  166.          S     R3,=F'81'                                                01660000
  167.          BC    4,FTERR9                                                 01670000
  168.          SLL   R3,2                                                     01680000
  169.          L     R9,PCERRLST(R3)                                          01690000
  170.          A     R3,=F'4'                                                 01700000
  171.          L     R8,PCERRLST(R3)                                          01710000
  172.          B     ADONE                                                    01720000
  173. *                                                                       01730000
  174. PCERR1   DC    C'PC file already exists.'                               01740000
  175. PCERR2   DC    C'Cannot determine PC disk space.'                       01750000
  176. PCERR3   DC    C'Insufficient PC disk space.'                           01760000
  177. PCERR4   DC    C'Cannot open PC file for write.'                        01770000
  178. PCERR5   DC    C'PC file not found.'                                    01780000
  179. PCERR6   DC    C'Cannot write to PC file.'                              01790000
  180. PCERR7   DC    C'Cannot determine length of PC file.'                   01800000
  181. PCERR8   DC    C'Cannot reposition PC file.'                            01810000
  182. PCERR9   DC    C'Unable to interpret host datastream.'                  01820000
  183. PCERR10  DC    C'Host did not respond to PC error.'                     01830000
  184. PCERR99  DS    0C                                                       01840000
  185. PCERRLST DC    A(PCERR1)                                                01850000
  186.          DC    A(PCERR2)                                                01860000
  187.          DC    A(PCERR3)                                                01870000
  188.          DC    A(PCERR4)                                                01880000
  189.          DC    A(PCERR5)                                                01890000
  190.          DC    A(PCERR6)                                                01900000
  191.          DC    A(PCERR7)                                                01910000
  192.          DC    A(PCERR8)                                                01920000
  193.          DC    A(PCERR9)                                                01930000
  194.          DC    A(PCERR10)                                               01940000
  195.          DC    A(PCERR99)                                               01950000
  196.          EJECT                                                          01960000
  197. *---------------------------------------------------------------------* 01970000
  198. *        VARIABLE AREA                                                * 01980000
  199. *---------------------------------------------------------------------* 01990000
  200. SAVEAREA DS    18F                                                      02000000
  201. RETCODE  DC    F'0'           SAVE THE RETURN CODE.                     02010000
  202. *                                                                       02020000
  203.          LTORG                                                          02030000
  204.          PRINT NOGEN                                                    02040000
  205.          REGEQU                                                         02050000
  206.          END                                                            02060000
  207.